File Manager

X7ROOT File Manager

Current Path: /usr/share/aclocal-1.16

ðŸ“ ..
ðŸ“„ amversion.m4(1.58 KB)
ðŸ“„ ar-lib.m4(2.02 KB)
ðŸ“„ as.m4(767 B)
ðŸ“„ auxdir.m4(2.35 KB)
ðŸ“„ cond-if.m4(1.01 KB)
ðŸ“„ cond.m4(1.01 KB)
ðŸ“„ depend.m4(7.11 KB)
ðŸ“„ depout.m4(2.58 KB)
ðŸ“„ dmalloc.m4(906 B)
ðŸ“„ extra-recurs.m4(738 B)
ðŸ“„ gcj.m4(649 B)
ðŸ“„ init.m4(7.84 KB)
ðŸ“„ install-sh.m4(681 B)
ðŸ“ internal
ðŸ“„ lead-dot.m4(641 B)
ðŸ“„ lex.m4(689 B)
ðŸ“„ lispdir.m4(2.1 KB)
ðŸ“„ maintainer.m4(1.62 KB)
ðŸ“„ make.m4(1.4 KB)
ðŸ“„ missing.m4(1.13 KB)
ðŸ“„ mkdirp.m4(1.32 KB)
ðŸ“„ obsolete.m4(1008 B)
ðŸ“„ options.m4(1.06 KB)
ðŸ“„ prog-cc-c-o.m4(1.65 KB)
ðŸ“„ python.m4(9.2 KB)
ðŸ“„ runlog.m4(718 B)
ðŸ“„ sanity.m4(2.58 KB)
ðŸ“„ silent.m4(1.87 KB)
ðŸ“„ strip.m4(1.36 KB)
ðŸ“„ substnot.m4(675 B)
ðŸ“„ tar.m4(4.37 KB)
ðŸ“„ upc.m4(836 B)
ðŸ“„ vala.m4(1.62 KB)

Editing: depout.m4

# Generate code to set up dependency tracking.              -*- Autoconf -*-

# Copyright (C) 1999-2018 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# _AM_OUTPUT_DEPENDENCY_COMMANDS
# ------------------------------
AC_DEFUN([_AM_OUTPUT_DEPENDENCY_COMMANDS],
[{
  # Older Autoconf quotes --file arguments for eval, but not when files
  # are listed without --file.  Let's play safe and only enable the eval
  # if we detect the quoting.
  # TODO: see whether this extra hack can be removed once we start
  # requiring Autoconf 2.70 or later.
  AS_CASE([$CONFIG_FILES],
          [*\'*], [eval set x "$CONFIG_FILES"],
          [*], [set x $CONFIG_FILES])
  shift
  # Used to flag and report bootstrapping failures.
  am_rc=0
  for am_mf
  do
    # Strip MF so we end up with the name of the file.
    am_mf=`AS_ECHO(["$am_mf"]) | sed -e 's/:.*$//'`
    # Check whether this is an Automake generated Makefile which includes
    # dependency-tracking related rules and includes.
    # Grep'ing the whole file directly is not great: AIX grep has a line
    # limit of 2048, but all sed's we know have understand at least 4000.
    sed -n 's,^am--depfiles:.*,X,p' "$am_mf" | grep X >/dev/null 2>&1 \
      || continue
    am_dirpart=`AS_DIRNAME(["$am_mf"])`
    am_filepart=`AS_BASENAME(["$am_mf"])`
    AM_RUN_LOG([cd "$am_dirpart" \
      && sed -e '/# am--include-marker/d' "$am_filepart" \
        | $MAKE -f - am--depfiles]) || am_rc=$?
  done
  if test $am_rc -ne 0; then
    AC_MSG_FAILURE([Something went wrong bootstrapping makefile fragments
    for automatic dependency tracking.  Try re-running configure with the
    '--disable-dependency-tracking' option to at least be able to build
    the package (albeit without support for automatic dependency tracking).])
  fi
  AS_UNSET([am_dirpart])
  AS_UNSET([am_filepart])
  AS_UNSET([am_mf])
  AS_UNSET([am_rc])
  rm -f conftest-deps.mk
}
])# _AM_OUTPUT_DEPENDENCY_COMMANDS

# AM_OUTPUT_DEPENDENCY_COMMANDS
# -----------------------------
# This macro should only be invoked once -- use via AC_REQUIRE.
#
# This code is only required when automatic dependency tracking is enabled.
# This creates each '.Po' and '.Plo' makefile fragment that we'll need in
# order to bootstrap the dependency handling code.
AC_DEFUN([AM_OUTPUT_DEPENDENCY_COMMANDS],
[AC_CONFIG_COMMANDS([depfiles],
     [test x"$AMDEP_TRUE" != x"" || _AM_OUTPUT_DEPENDENCY_COMMANDS],
     [AMDEP_TRUE="$AMDEP_TRUE" MAKE="${MAKE-make}"])])

X7ROOT File Manager

Editing: depout.m4

Upload File

Create Folder