File Manager

X7ROOT File Manager

Current Path: /usr/share/aclocal

ðŸ“ ..
ðŸ“„ bison-i18n.m4(1.88 KB)
ðŸ“„ codeset.m4(842 B)
ðŸ“„ extern-inline.m4(4.27 KB)
ðŸ“„ fcntl-o.m4(4.56 KB)
ðŸ“„ fontutil.m4(13.83 KB)
ðŸ“„ freetype2.m4(6.18 KB)
ðŸ“„ gettext.m4(15.49 KB)
ðŸ“„ glibc2.m4(830 B)
ðŸ“„ glibc21.m4(907 B)
ðŸ“„ gpg-error.m4(4.65 KB)
ðŸ“„ gpgrt.m4(4.61 KB)
ðŸ“„ iconv.m4(9.06 KB)
ðŸ“„ intdiv0.m4(2.35 KB)
ðŸ“„ intl.m4(11.84 KB)
ðŸ“„ intldir.m4(917 B)
ðŸ“„ intlmacosx.m4(2.47 KB)
ðŸ“„ intmax.m4(1.1 KB)
ðŸ“„ inttypes-pri.m4(1.22 KB)
ðŸ“„ inttypes_h.m4(1020 B)
ðŸ“„ lcmessage.m4(1.33 KB)
ðŸ“„ lib-ld.m4(3.6 KB)
ðŸ“„ lib-link.m4(32.28 KB)
ðŸ“„ lib-prefix.m4(8.27 KB)
ðŸ“„ libcurl.m4(10.91 KB)
ðŸ“„ libgcrypt.m4(6.09 KB)
ðŸ“„ libtool.m4(298.69 KB)
ðŸ“„ libxml.m4(7.7 KB)
ðŸ“„ libxslt.m4(7.93 KB)
ðŸ“„ lock.m4(1.43 KB)
ðŸ“„ longlong.m4(4.63 KB)
ðŸ“„ ltargz.m4(2.51 KB)
ðŸ“„ ltdl.m4(29.33 KB)
ðŸ“„ ltoptions.m4(14.17 KB)
ðŸ“„ ltsugar.m4(4.28 KB)
ðŸ“„ ltversion.m4(699 B)
ðŸ“„ lt~obsolete.m4(6 KB)
ðŸ“„ mysql.m4(4.12 KB)
ðŸ“„ nls.m4(1.19 KB)
ðŸ“„ pkg.m4(12.37 KB)
ðŸ“„ po.m4(18.52 KB)
ðŸ“„ printf-posix.m4(1.54 KB)
ðŸ“„ progtest.m4(3.02 KB)
ðŸ“„ size_max.m4(2.99 KB)
ðŸ“„ stdint_h.m4(995 B)
ðŸ“„ threadlib.m4(14.8 KB)
ðŸ“„ uintmax_t.m4(1.09 KB)
ðŸ“„ visibility.m4(3.27 KB)
ðŸ“„ wchar_t.m4(818 B)
ðŸ“„ wint_t.m4(1.03 KB)
ðŸ“„ xsize.m4(406 B)

Editing: lib-ld.m4

# lib-ld.m4 serial 6
dnl Copyright (C) 1996-2003, 2009-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl Subroutines of libtool.m4,
dnl with replacements s/_*LT_PATH/AC_LIB_PROG/ and s/lt_/acl_/ to avoid
dnl collision with libtool.m4.

dnl From libtool-2.4. Sets the variable with_gnu_ld to yes or no.
AC_DEFUN([AC_LIB_PROG_LD_GNU],
[AC_CACHE_CHECK([if the linker ($LD) is GNU ld], [acl_cv_prog_gnu_ld],
[# I'd rather use --version here, but apparently some GNU lds only accept -v.
case `$LD -v 2>&1 </dev/null` in
*GNU* | *'with BFD'*)
  acl_cv_prog_gnu_ld=yes
  ;;
*)
  acl_cv_prog_gnu_ld=no
  ;;
esac])
with_gnu_ld=$acl_cv_prog_gnu_ld
])

dnl From libtool-2.4. Sets the variable LD.
AC_DEFUN([AC_LIB_PROG_LD],
[AC_REQUIRE([AC_PROG_CC])dnl
AC_REQUIRE([AC_CANONICAL_HOST])dnl

AC_ARG_WITH([gnu-ld],
    [AS_HELP_STRING([--with-gnu-ld],
        [assume the C compiler uses GNU ld [default=no]])],
    [test "$withval" = no || with_gnu_ld=yes],
    [with_gnu_ld=no])dnl

# Prepare PATH_SEPARATOR.
# The user is always right.
if test "${PATH_SEPARATOR+set}" != set; then
  # Determine PATH_SEPARATOR by trying to find /bin/sh in a PATH which
  # contains only /bin. Note that ksh looks also at the FPATH variable,
  # so we have to set that as well for the test.
  PATH_SEPARATOR=:
  (PATH='/bin;/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
    && { (PATH='/bin:/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
           || PATH_SEPARATOR=';'
       }
fi

ac_prog=ld
if test "$GCC" = yes; then
  # Check if gcc -print-prog-name=ld gives a path.
  AC_MSG_CHECKING([for ld used by $CC])
  case $host in
  *-*-mingw*)
    # gcc leaves a trailing carriage return which upsets mingw
    ac_prog=`($CC -print-prog-name=ld) 2>&5 | tr -d '\015'` ;;
  *)
    ac_prog=`($CC -print-prog-name=ld) 2>&5` ;;
  esac
  case $ac_prog in
    # Accept absolute paths.
    [[\\/]]* | ?:[[\\/]]*)
      re_direlt='/[[^/]][[^/]]*/\.\./'
      # Canonicalize the pathname of ld
      ac_prog=`echo "$ac_prog"| sed 's%\\\\%/%g'`
      while echo "$ac_prog" | grep "$re_direlt" > /dev/null 2>&1; do
        ac_prog=`echo $ac_prog| sed "s%$re_direlt%/%"`
      done
      test -z "$LD" && LD="$ac_prog"
      ;;
  "")
    # If it fails, then pretend we aren't using GCC.
    ac_prog=ld
    ;;
  *)
    # If it is relative, then search for the first ld in PATH.
    with_gnu_ld=unknown
    ;;
  esac
elif test "$with_gnu_ld" = yes; then
  AC_MSG_CHECKING([for GNU ld])
else
  AC_MSG_CHECKING([for non-GNU ld])
fi
AC_CACHE_VAL([acl_cv_path_LD],
[if test -z "$LD"; then
  acl_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
  for ac_dir in $PATH; do
    IFS="$acl_save_ifs"
    test -z "$ac_dir" && ac_dir=.
    if test -f "$ac_dir/$ac_prog" || test -f "$ac_dir/$ac_prog$ac_exeext"; then
      acl_cv_path_LD="$ac_dir/$ac_prog"
      # Check to see if the program is GNU ld.  I'd rather use --version,
      # but apparently some variants of GNU ld only accept -v.
      # Break only if it was the GNU/non-GNU ld that we prefer.
      case `"$acl_cv_path_LD" -v 2>&1 </dev/null` in
      *GNU* | *'with BFD'*)
        test "$with_gnu_ld" != no && break
        ;;
      *)
        test "$with_gnu_ld" != yes && break
        ;;
      esac
    fi
  done
  IFS="$acl_save_ifs"
else
  acl_cv_path_LD="$LD" # Let the user override the test with a path.
fi])
LD="$acl_cv_path_LD"
if test -n "$LD"; then
  AC_MSG_RESULT([$LD])
else
  AC_MSG_RESULT([no])
fi
test -z "$LD" && AC_MSG_ERROR([no acceptable ld found in \$PATH])
AC_LIB_PROG_LD_GNU
])

X7ROOT File Manager

Editing: lib-ld.m4

Upload File

Create Folder